are there any TypeInfo helper somewhere ?

are there any TypeInfo helper  somewhere ?

the TypeInfo unit is somewhat complex to handle, but I don't like how the Rtti context handles things...

I'm looking for something like this :

type
  TTypeInfoHelper = record helper for TTypeInfo
    function DataPtr(Offset: Integer): Pointer; inline;
    function DataByte(Offset: Integer): Byte; inline;
    function DataLong(Offset: Integer): Integer; inline;
    function RecordFieldsOfs : Integer;
    function RecordFieldCount: Integer;
    function RecordFieldType(Index: Integer): PRecordTypeField;
  end;

  TRecordTypeFieldHelper = record helper for TRecordTypeField
    function InstanceSize: Integer;
  end;

function TTypeInfoHelper.DataPtr(Offset: Integer): Pointer;
var
  Value: PByte;
begin
  Value := PByte(TypeData);
  Inc(Value, Offset);
  Result := Value;
end;

function TTypeInfoHelper.DataByte(Offset: Integer): Byte;
begin
  Result := PByte(DataPtr(Offset))^;
end;

function TTypeInfoHelper.DataLong(Offset: Integer): Integer;
begin
  Result := PInteger(DataPtr(Offset))^;
end;

function TTypeInfoHelper.RecordFieldsOfs: Integer;
var
  NumOps: Byte;
begin
  Result := 2 * SizeOf(Integer) + TypeData.ManagedFldCount * SizeOf(TManagedField);
  NumOps := DataByte(Result);
  Inc(Result, 1 + NumOps * SizeOf(Pointer));
end;

function TTypeInfoHelper.RecordFieldCount: Integer;
begin
  if Kind <> tkRecord then
    Exit(0);
  Result := DataLong(RecordFieldsOfs);
end;

function TTypeInfoHelper.RecordFieldType(Index: Integer): PRecordTypeField;
var
  Offset: Integer;
  NumOps: Byte;
begin
  if (Kind <> tkRecord) or (Index < 0) then
    Exit(nil);
  Offset := RecordFieldsOfs;
  if DataLong(Offset) <= Index then
    Exit(nil);
  Inc(Offset, SizeOf(Integer));
  Result := DataPtr(Offset);
  while Index > 0 do
  begin
    Inc(Offset, Result.InstanceSize);
    Result := DataPtr(Offset);
    Dec(Index);
  end;
end;

function TRecordTypeFieldHelper.InstanceSize: Integer;
begin
  Result := SizeOf(TRecordTypeField) - 255 + Length(Name) + AttrData.Len;
end;

{ TForm1 }

procedure TForm1.Analyse(Instance, TypeInfo: Pointer);
var
  Info  : PTypeInfo absolute TypeInfo;
  Index : Integer;
  Field : PRecordTypeField;
begin
  Memo1.Lines.Add(Info.Name);
  case Info.Kind of
    tkRecord:
    begin
      Memo1.Lines.Add('tkRecord');
      Memo1.Lines.Add(' SizeOf = ' + IntToStr(Info.TypeData.RecSize));
      Memo1.Lines.Add(' RecordCount = ' + IntToStr(Info.RecordFieldCount));
      for Index := 0 to Info.RecordFieldCount - 1 do
      begin
        Field := Info.RecordFieldType(Index);
        Memo1.Lines.Add(' ' + Field.Name);
        Analyse(PByte(Instance) + Field.Field.FldOffset, Field.Field.TypeRef^);
      end;
    end;
  end;
end;